技術系備忘録​/C++​/VisualStudio​/MSBuild.exeのパスを解決して実行

使い方

> MSBuild.bat c:\app\app.vcxproj

こんな感じで使うと、インストールされている最新の MSBuild.exe でビルドを行います。

VisualStudio2019、2017、2015 の環境までは確認しています。

MSBuild.bat

:: MSBuild.exe %*

@echo off
setlocal
:: cd /d %~dp0

set PF32=%ProgramFiles(x86)%
if not exist "%PF32%" set PF32=%ProgramFiles%

set VsWherePath="%PF32%\Microsoft Visual Studio\Installer\vswhere.exe"

:: vs2019 or later
for /f "usebackq tokens=*" %%i in (`%VsWherePath% -latest -requires Microsoft.Component.MSBuild -find MSBuild\**\Bin\MSBuild.exe`) do (
	if exist "%%i" (
		set MSBuildPath="%%i"
		goto :run
	)
)

:: vs2017 or earlier
for /f "usebackq tokens=1* delims=: " %%i in (`%VsWherePath% -latest -requires Microsoft.Component.MSBuild`) do (
	if /i "%%i"=="installationPath" (
		if exist "%%j\MSBuild\15.0\Bin\MSBuild.exe" (
			set MSBuildPath="%%j\MSBuild\15.0\Bin\MSBuild.exe"
			goto :run
		)
		if exist "%%j\MSBuild\14.0\Bin\MSBuild.exe" (
			set MSBuildPath="%%j\MSBuild\14.0\Bin\MSBuild.exe"
			goto :run
		)
		if exist "%%j\MSBuild\12.0\Bin\MSBuild.exe" (
			set MSBuildPath="%%j\MSBuild\12.0\Bin\MSBuild.exe"
			goto :run
		)
	)
)

:run
if not exist %MSBuildPath% (
	echo "MSBuild.exe not find"
	exit /b 1
)

echo on
%MSBuildPath% %*

備考

VisualStudio2019 の vswhere.exe には -find っていうオプションが追加されたようで、それを使うのが王道らしいので、それを使っています。
が、当然 VisualStudio2019 が未インストールの環境では、-find を指定してもエラーになります。
で、エラーが返ってきてもファイルの有無チェックで弾くことで VisualStudio2019 未満向けの処理に流れるっていう寸法です。
あんまりスマートじゃないやり方な気がしますが、他に妙案が思いつかないです・・。
もしもっと良い方法があればご助言頂けると幸いです。